Stata tip 133: Box plots that show median and quartiles only

1 Introduction

Box plots (for example, Tukey [1977]) are well known as summary plots for univariate distributions. In the most common design, as supported by graph box and graph hbox, a central box for each variable or group shown on a graph depicts median and lower and upper quartiles. The length of the box is thus the difference or distance

upper quartile − lower quartile

known as the interquartile range. What is shown beyond the box may include individual data points if any lie more than 1.5 times the interquartile range from the nearer quartile. Otherwise, capped lines known as whiskers are shown; these extend to the outermost data points not shown individually.

A detail of importance to what follows is that no whiskers are shown if no value is less than the lower quartile or more than the upper quartile. That can happen with data, especially with very small samples or variables showing many ties, such as grades (ordered responses coded 1 to 5, or whatever), counts, or integer scores.

Requests are often made for Stata code to produce truncated box plots that show only median and quartiles. This tip shows how to get such plots without elaborate programming.

2 Median and quartiles only

Wanting only median and quartiles echoes a very common twofold practice:

Show a summary of level (say, a mean) of some variable or group by a marker, in this context most often a filled circle.

Indicate variability by capped or uncapped spikes extending above and below the marker for level by some multiple of the standard deviation of the data or the standard error of the mean.

Such plots thus include, but are not restricted to, displays of confidence intervals. Wanting plots that show median and quartiles is natural whenever there is interest or use in summaries that are more robust or resistant than the mean and the standard deviation, or summaries dependent on those statistics. For example, the mean, and even more the standard deviation, can be highly sensitive to outliers, especially in small samples. Wanting to use box plot conventions for showing median and quartiles also reduces the scope for misreading such displays as based on means and standard deviations or standard errors.

Firing up a typical box plot, say, with

. sysuse auto

. graph box mpg, over(foreign) ylabel(, angle(horizontal))

may suggest that a way to proceed is just to make the whiskers and individual points invisible. We could add further options to do that:

. graph box mpg, over(foreign) ylabel(, angle(horizontal)) cwhiskers> lines(lcolor(none)) marker(1, ms(none))

This trick is always worth knowing, but it is not a perfect solution. If there are two or more kinds of markers, all must be removed. Further, and more serious in practice, such a technique makes elements invisible without removing the space needed to show them. At worst, the result is that the boxes occupy just a small fraction of the plot region, which is not usually what is wanted. The same comments apply to removing or hiding elements in the Graph Editor.

Elsewhere (Cox 2009, 2013) there is detailed discussion of how you can make your own box plots, or variations on them, by first calculating the summary statistics you want to show and then calling up graph twoway. This approach is necessary if you want to show something quite far removed from what is offered by graph box or graph hbox. Examples might be showing means as well as medians and quartiles or using customized whiskers that extend to particular percentiles (for example, 5% and 95%) or the sample extremes.

3 Collapsing to samples of three

The main focus of this tip is another method that is flexible, easy to understand, and easy to implement. Suppose we reduce each group or variable to three values that are the median and quartiles. Then if such values are now the data, with samples of size 3, Stata’s rules imply that the smallest and largest values are taken as the quartiles and the middlemost (a splendid word for the one in the middle) is taken as the median. Thus, a box plot will then show the median and quartiles of the original data, and only those, with no whiskers or individual data points. Skip or skim ahead to (*) if you are unsurprised by that or happy to believe that there is a detailed explanation.

It is standard that the median of any odd number of values, including three, is the middlemost. What may be a little more surprising, or at least unexpected, is the rule for quartiles. Stata’s recipe is documented at [R] summarize.

For sample size n, we consider values x ordered such that $x_{\left(1\right)}\le ···\le x_{(n)}$ . For the pth percentile, we apply weights w(i) scaled to sum to n and cumulate $P={\displaystyle {\sum }_{j=1}^i{w}_i}$ summarize reports as percentile

$(x_{(i-1)}+x_{(i)})/2 \text{if}\hspace{0.17em}P=np/100$

and x _{( i )} otherwise.

For n = 3, p = 25, and np/100 = 75/100. With equal weights $w_i=1$ , P runs 1, 2, and 3 for three ordered values, so we use x(1), the lowest value, as the lower quartile. Similarly, for n = 3, p = 75, $np/100 =225/100$ , so we use x _{( 3 )}, the largest value, as the upper quartile.

The case of unequal weights is not relevant to this point. We need to know only that if presented with three values, Stata’s box plot commands will echo precisely those values as median and quartiles. It is not contradictory that those three values could have been produced by a calculation using weights of any kind.

These rules naturally do not exclude the possibility that two or even three of those summaries coincide numerically, finally producing a degenerate box in a box plot.

(*) Reduction to sets or subsets of three values can be achieved by an easy collapse and reshape of the data. The dataset in memory will thus be destroyed. Hence, it should be save d first or beforehand. Or you should use preserve before all that follows, and restore afterward, to get the original dataset back in memory when graphing is finished. See the help files for these commands if the idea is new to you.

Before we do this, there is one small warning. On a collapse, variable labels you want to be used as axis titles in the graph may disappear. If they are long and complicated, you may find it irritating to have to type them again. One way to store them safely is to put them in local macros. Continuing our example with the auto data, let’s type

. local ytitle: var label mpg

. local xtitle: var label foreign

Note that we do not need to type the variable label itself. Stata knows what it is, and the so-called extended macro function : var label is the hook to retrieve it. This is particularly useful if the variable label is long or complicated, say, with any or all of superscripts, subscripts, Greek letters, Stata Markup and Control Language, or other unusual characters. help extended macro functions gives you access to documentation on this and several other useful hooks.

Now to the nub of the matter. The call to collapse will be a single line, such as

. collapse (p25) mpg25=mpg (p50) mpg50=mpg (p75) mpg75=mpg, by(foreign)

For one variable, we need to ask for median and quartiles of that variable, here as percentiles for 25%, 50%, and 75%. We often want to do that separately by distinct combinations of one or more variables. As far as collapse is concerned, the new variables containing median and quartiles could be called anything legal, such as frog, toad, and newt. Using the same prefix (here mpg) and different numeric suffixes looks ahead to what will be easiest when we reshape. If we overlook that, we will likely just have to rename some variables.

Let’s see what that produces and what a reshape produces in turn.

Now we can draw our graph (figure 1):

. graph box mpg, over(foreign) ylabel(, angle(horizontal)) ytitle("`ytitle´")

> b1title("`xtitle´")

Figure 1.

Box plot of miles per gallon for foreign and domestic cars, showing medians and quartiles only

4 Complications: More variables, more categories, weights,…

For more variables, we will need to work a bit more in specifying what is wanted to collapse. This example with temperatures for cities in the United States is reproducible, but the graph is not shown for reasons of space. The vertical axis labels are a nod to readers in most countries of the world more accustomed to Celsius temperatures: 32^◦F = 0^◦C, 50^◦F = 10^◦C, and so forth.

. sysuse citytemp, clear

. collapse (p25) Jan25=tempjan Jul25=tempjuly (p50) Jan50=tempjan > Jul50=tempjuly (p75) Jan75=tempjan Jul75=tempjul, by(region)

. reshape long Jan Jul, i(region) j(pctile)

. label var Jan "January"

. label var Jul "July"

. graph box Jan Jul, over(region) ytitle(Mean temperature (&degreeF))> ylabel(, angle(horizontal)) yline(32) ylabel(14(18)86)

More variables as categorical classifiers? Just feed them all to the by() option of collapse and the i() option of reshape.

Weights? Spell them out to collapse. We do not need to worry about them beyond that point because the graphical problem is to deal with our already weighted medians and quartiles.

Anyone doing this often would be well advised to write a do-file or command that automates the process, but that goes further than the aim of this tip.

Supplemental Material

Supplemental Material, gr0081 - Stata tip 133: Box plots that show median and quartiles only

Supplemental Material, gr0081 for Stata tip 133: Box plots that show median and quartiles only by Nicholas J. Cox in The Stata Journal